LARGE Function
Returns the k-th largest number in a set.
Category
Statistical
Available in
All versions, Microsoft 365
Returns
A number
Overview
LARGE(range, 1) is the largest value (same as MAX), LARGE(range, 2) the second largest, and so on. Tied values each take a position.
It's the classic way to build a top-3 or top-10 list.
Syntax
=LARGE(array, k) Explain
Arguments
| Argument | Required? | What it does |
|---|---|---|
| array | Yes | The range or array of numbers. |
| k | Yes | The position from the top: 1 = largest. |
Examples
Example 1 — Top 3 sales results
Column D holds the place; lock the range with $ so the formula fills down.
E2fx=LARGE($C$2:$C$8,D2)
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Rep | Region | Sales | Place | Sales |
| 2 | Ana | North | 62000 | 1 | 71250 |
| 3 | Ben | South | 48500 | 2 | 62000 |
| 4 | Cy | North | 50000 | 3 | 55400 |
| 5 | Di | East | 71250 | ||
| 6 | Ed | South | 39800 | ||
| 7 | Fay | North | 55400 | ||
| 8 | Gus | East | 48500 |
=LARGE($C$2:$C$8,D2) Explain
Example 2 — Sum of the top 3
Give LARGE several positions at once.
=SUM(LARGE(C2:C8,{1,2,3})) Explain
Returns 188,650.
Example 3 — Who's top?
Pair LARGE with XLOOKUP (or INDEX/MATCH) to return the name.
=XLOOKUP(LARGE(C2:C8,1),C2:C8,A2:A8) Explain
Returns Di.
Common mistakes
- #NUM! k is 0 or less, or bigger than the number of values.
- Ties. LARGE(…,2) and LARGE(…,3) can return the same number when values tie, and a lookup on it will find the first match twice.
Notes

Author
Kyle Stott
Certified Microsoft Excel Expert
Kyle has worked professionally with Microsoft Excel for over a decade and has consulted on and taught Excel best practices to over 400 companies across 30+ countries.